Blijbol.nl

Blijbol, happy business

Links About Blijbol Guestbook

Home News Games Software Game Maker

Downloaded 1,270 times

Virus

Carefully watch mutating digits

More screenshots: 1 2 3 4 5 6

Downloads

Please read the licence on the left.

v1.1a
(8xp; < 0.01 MB)

Links to here:

Description

Virus is a nice puzzle game. You have to press last appeared number on the screen, and every time you do this a new number appears. It gets harder and harder because old numbers don't get removed. You can play the game in two different modes: single player and multiplayer. In single player mode your score increases on each good move. The game ends when you make a mistake. In the turn-based multiplayer mode you play against a human opponent, where both players control their own playing fields. The first one who makes a mistake, loses the game. The game is only available for graphing calculators.

Codes

Licence: You are only allowed to change the source code for private usage. Any adapted version of the program cannot be distributed. The names 'Jeroen van der Gun' and 'Blijbol', and the website 'www.blijbol.nl' must remain, and have to be easily viewable from within the program. Copyright © 2006 Jeroen van der Gun.

`prgmVIRUS`

::
:ClrHome
:Normal
:Float
:getKey
:Lbl A
:Disp "Blijbol","Happy business","","www.blijbol.nl","","(C) 2006 Jeroen","van der Gun"
:While getKey=0
:End
:Lbl D
:ClrHome
:Menu("     VIRUS      "," Single Player",B," Multiplayer",E," About",G," Quit",C)
:Lbl G
:Disp "","Blijbol Virus","","Version 1.1a","","games.blijbol.nl"
:While getKey=0
:End
:Goto A
:Lbl E
:Disp "Player:"
:For(G,3,8)
:Output(G,8,"!!")
:End
:{6,14}→dim([J])
:randInt(1,2)→I
:Goto F
:Lbl B
:Disp "Score: 0"
:{6,16}→dim([J])
:0→D
:0→I
:Lbl F
:Disp "----------------"
:Fill(0,[J])
:While 1
:randInt(1,6)→E
:If I=0
:randInt(1,16)→F
:If I=1
:Then
:Output(1,9,"left ")
:randInt(1,7)→F
:End
:If I=2
:Then
:Output(1,9,"right")
:randInt(8,14)→F
:End
:0→A
:Repeat A≠0 and A≠[J](E,F)
:randInt(1,9)→A
:End
:If A≤3
:91+A→B
:If A≥4 and A≤6
:78+A→B
:If A≥7
:65+A→B
:A→[J](E,F)
:If I=2
:Then
:Output(E+2,F+2,A)
:Else
:Output(E+2,F,A)
:End
:0→C
:While C=0
:getKey→C
:End
:If I=2
:F+2→F
:If C≠B
:Then
:For(H,1,5)
:Output(E+2,F," ")
:For(G,1,150)
:End
:Output(E+2,F,A)
:For(G,1,150)
:End
:End
:ClrHome
:Output(4,4,"Game Over!")
:If I=0
:Then
:Output(5,4,"Score:")
:Output(5,11,D)
:Else
:If I=1
:Then
:Output(5,4,"Right wins!")
:Else
:Output(5,4,"Left wins!")
:End
:End
:While getKey=0
:End
:Goto D
:End
:If I=0
:Then
:D+1→D
:Output(1,8,D)
:End
:If I≠0
:Then
:I+1→I
:If I=3
:1→I
:End
:End
:Lbl C

Version 1.1a (stable)

Release date: 30 January 2006
Language: English
System requirements: Texas Instruments graphing calculator running TI-83 Plus or TI-84 Plus operating system (Silver Edition is also fine), 994 bytes free RAM memory or archive space for storage (during use more RAM memory is needed)

Project status

A stable version of this product has been released. The project was announced at 12 January 2006.

Credits

This game has been created by Jeroen van der Gun in TI-Basic.

More for your calculator

Games: Snake, Decoder, Connect4, Drop, 1000
Software: Color Contrast Checker, Unix Time Converter, Base Converter, Wrongs, Quadratic formula

Comments

No comments have been posted yet. Use the form to post one.